実行されるコマンドのパラメータとして、コントロールの値が必要なことがよくあります。状態が変わるたびにコントロールを照会しなくても済むように、コントロールの値を文字列「#1」としてコマンドに埋め込むことができます。コントロールの値が変わると、そのコマンドを送るときに「#1」がコントロールの実際の値に置き換えられます。複数の値を持つグループは異なるコンポーネントの値に対して、「#2」、「#3」などを使用します。たとえば、3 つのフィールドがある float フィールド グループは、「#1」、「#2」、「#3」を使用して、コマンドで各フィールドの値を表すことができます。

global proc testFuncArg1(string $arg1){
    print("testFuncArg1:" + $arg1 + "\n");
}

global proc testFuncArg2(string $arg1, string $arg2){
    print("testFuncArg1:" + $arg1 + ", " + $arg2 + "\n");
}

global proc testFuncArg3(string $arg1, string $arg2, string $arg3){
    print("testFuncArg1:" + $arg1 + ", " + $arg2 + ", " + $arg3 + "\n");
}

global proc testFuncArg4(string $arg1, string $arg2, string $arg3, string $arg4){
    print("testFuncArg1:" + $arg1 + ", " + $arg2 + ", " + $arg3 + ", " + $arg4 + "\n");
}

global proc testFuncArg5(string $arg1, string $arg2, string $arg3, string $arg4, string $arg5){
    print("testFuncArg1:" + $arg1 + ", " + $arg2 + ", " + $arg3 + ", " + $arg4 + ", " + $arg5 + "\n");
}

window;
columnLayout;

// #1 は 0 (NULL)となります。ボタンに使っても意味がなさそう。
button -c "testFuncArg1 #1";

// #1 はフィールドの文字列。
textField -changeCommand "testFuncArg1 #1";

// #1 はフィールドの数値。
floatSliderGrp -field true -changeCommand "testFuncArg1 #1";

// #1~#4 にはそれぞれのフィールドの値
floatFieldGrp -numberOfFields 4 -changeCommand "testFuncArg4 #1 #2 #3 #4";

// #1はチェックのvalue。指定している"-changeCommand番号"目のチェックのvalue。
checkBoxGrp -numberOfCheckBoxes 2 -changeCommand1 "testFuncArg1 #1" -changeCommand2 "testFuncArg1 #1";

//　-changeCommandでは、変更したチェックのvalueが来るものの、何番目のチェックのvalueかは分からず。
//checkBoxGrp -numberOfCheckBoxes 2 -changeCommand "testFuncArg1 #1";

// #1 には選んだmenuItemのラベル名
optionMenuGrp -label "Colors" -changeCommand "testFuncArg1 #1";
menuItem -label "Red";
menuItem -label "Green";

// #1 にはアイコンのvalue値。onCommand/offCommandのどちらでも、#1にはアイコンのvalue値。
// onCommandは常に1、offCommandは常に0となってしまうので、
// changeCommandに使わないと#1の意味がない。
iconTextCheckBox -style "iconAndTextHorizontal" -image1 "cone.png" -label "cone" -changeCommand "testFuncArg1 #1";

// #1はどのコマンドでも使われない・・・。
textScrollList -numberOfRows 3 -allowMultiSelection true
    -append "one"      -append "two"      -append "three"
    -showIndexedItem 3
    -selectCommand "testFuncArg1 #1"; // error!

// radioButtonGrpは使い所が難しいです。
// -changeCommandに設定すると、ラジオボタンを選んだときと、選択が外れる（他に移る）ときの二回で、それぞれ1と0が#1に設定されます。
// -shareCollectionに設定された先のradioButtonGrpは無関係なため、下記の例では"Yellow" "Orange" "Purple"には反応しません。
string $group1 = `radioButtonGrp -numberOfRadioButtons 3
    -label "Colors" -labelArray3 "Red" "Blue" "Green"
    -changeCommand "testFuncArg1 #1"`;
radioButtonGrp -numberOfRadioButtons 3 -shareCollection $group1
    -label "" -labelArray3 "Yellow" "Orange" "Purple";

showWindow;

import maya.cmds as cmds

def testFuncArg(*args):
    print('testFuncArg:', args)

cmds.window()
cmds.columnLayout()
cmds.button(c=testFuncArg) # #1 は False (NULL)
cmds.textField(changeCommand=testFuncArg) # #1 はフィールドの値
cmds.textFieldButtonGrp(buttonCommand=testFuncArg, changeCommand=testFuncArg) # buttonCommandは何も来ない。changeCommandは文字列が来る
cmds.floatSliderGrp(field=True, changeCommand=testFuncArg)
cmds.floatFieldGrp(numberOfFields=4, changeCommand=testFuncArg) # #1~#4 にはそれぞれのフィールドの値
cmds.optionMenuGrp(label="Colors", changeCommand=testFuncArg) # #1 には選んだmenuItemのラベル名
cmds.menuItem(label="Red")
cmds.menuItem(label="Green")
cmds.radioButtonGrp(numberOfRadioButtons=4, changeCommand=testFuncArg, label='Colors', labelArray4=['Red', 'Blue', 'Green', 'Purple'] )

cmds.showWindow()