// showCurrentProjectUI.mel
// 次のスクリプトを実行すると、メニューセットメニューの右隣に、現在のプロジェクト名を表示するテキストフィールドを作成します。
//
// showCurrentProjectUI(true); // UIを作ります。
// または
// showCurrentProjectUI(false); // UIを削除します。
//
//

// UIの更新をします。
global proc myCurrentProjectUpdateUI()
{
    global string $gCurrentProjUI;
    if ( `textField -q -ex $gCurrentProjUI` == false ){
        // この関数が呼び出されるときには必ずUIがあるはずですが、念のためチェック。
        // UIがなければ何もせずに終わります。
        return;
    }

    // プロジェクトのルートディレクトリを取得します。
    string $rootDir = `workspace -q -rootDirectory`;

    // パスの終わりの文字が/の場合、削除して見た目を良くします。（例： D:/test/ -> D:/test）
    if ( endsWith( $rootDir, "/") ){
        $rootDir = `substring $rootDir 1 (size($rootDir)-1)`;
    }

    // 文字が長すぎる場合は、ドライブ名とプロジェクト名のみ残します。
    string $displayPath = $rootDir;
    if ( size($rootDir) > 25 ){
        string $buffer[];
        tokenize $rootDir "/" $buffer;
        if (size($buffer) > 3 ){
            $displayPath = $buffer[0] + "/.../" + $buffer[size($buffer)-1];
        }
    }

    textField -e -tx ("PROJECT: "+$displayPath) $gCurrentProjUI;
    textField -e -ann $rootDir $gCurrentProjUI; // UI上でマウスを置いておくと、アノテーションにフルパスを表示。

}

global proc showCurrentProjectUI( int $visible )
{
    global string $gCurrentProjUI; // プロジェクト名を表示するUI。
    global int $gShowCurrentProjectScriptJobId; // プロジェクト名を更新するスクリプトジョブのID。

    if ( $visible == true ){
        // UIを表示します。
        // まだ無ければ作ります。
        if ( `textField -q -ex $gCurrentProjUI` ){
            // 既に表示されているので、何もせずに終わります。
            return;
        }

        global string $gMenuModeButton; // メニューのカテゴリを選ぶオプションメニューの名前

        //　新しくプロジェクト名を表示するためのUIを作ります。
        $gCurrentProjUI = `textField -ed false -w 200 -text "D:/test" -p "optionMenuForm" currentProjectInfo`;

        formLayout -e
            -an $gMenuModeButton right
            -af $gCurrentProjUI top 1
            -ac $gCurrentProjUI left 1 $gMenuModeButton
            -af $gCurrentProjUI right 1
            -af $gCurrentProjUI bottom 1
                optionMenuForm;

        $gShowCurrentProjectScriptJobId = `scriptJob -e "workspaceChanged" "myCurrentProjectUpdateUI"`;
        myCurrentProjectUpdateUI(); // 始めにUIを一度更新します。

    } else {
        // UIを非表示にします。
        // UIとスクリプトジョブを削除します。
        if ( `textField -q -ex $gCurrentProjUI` ){
            scriptJob -kill $gShowCurrentProjectScriptJobId;
            deleteUI $gCurrentProjUI;
        }
    }
}

showCurrentProjectUI(true); // UIを作ります。